0 POKE808,239:REM DISABLE STOP KEY
10 REM ******************************
11 REM * MAELZEL'S MODERN METRONOME *
12 REM *     BY  ROBERT S. OWEN     *
13 REM *        DEDICATED TO        *
14 REM *       JIMMY THOMPSON       *
15 REM ******************************
100 GOSUB5000
300 PRINTCHR$(150)
310 POKES,0:POKEVIC+2,136:POKE198,0
311 PRINTCHR$(19)TAB(38)SP$" "
312 PRINTCHR$(19)TAB(38)TP$"_"
320 GOSUB7300:GETA$:IFA$=""THEN320
321 IFA$="3"THEN320
322 IFA$<>CHR$(13)THEN325
324 GOTO380
325 IFA$<>CHR$(141)THEN330
327 PRINTCHR$(19)TAB(38)TP$" "
328 GOTO7000
330 IFA$<"1"ORA$>"9"THEN320
331 T$=A$:PRINTCHR$(19)TAB(28)TP$CHR$(18)T$"  "
340 GOSUB7300:GETA$:IFA$=""THEN340
345 IFA$<"0"ORA$>"9"THEN340
346 IFT$="2"THENIFA$>"0"THEN340
350 T$=T$+A$:PRINTCHR$(19)TAB(28)TP$CHR$(18)T$" "
351 IFVAL(T$)>39THEN380
360 GOSUB7300:GETA$:IFA$=""THEN360
365 IFA$<"0"ORA$>"9"THEN360
370 T$=T$+A$
380 PRINTCHR$(19)TAB(28)TP$CHR$(146)T$" "
390 TS=.935*VAL(T$)+35.6:POKEVIC+1,TS
395 PRINTCHR$(19)TAB(38)TP$" "
396 PRINTCHR$(19)TAB(38)BT$"_"
520 GOSUB7300:GETA$:IFA$=""THEN520
521 IFA$=CHR$(13)THEN580
525 IFA$<"1"ORA$>"8"THEN520
530 B$=A$:PRINTCHR$(19)TAB(28)BT$CHR$(18)B$"/ "
540 GOSUB7300:GETA$:IFA$=""THEN540
541 IFA$=CHR$(13)THEN540
545 IFA$<>"1"ANDA$<>"2"ANDA$<>"4"ANDA$<>"8"THEN540
550 BB$=A$:PRINTCHR$(19)TAB(28)BT$CHR$(146)B$"/"BB$
580 PRINTCHR$(19)TAB(38)BT$" "
581 PRINTCHR$(19)TAB(38)GG$"_"
610 GOSUB7300:GETA$:IFA$<>CHR$(13)THEN610
680 PRINTCHR$(19)TAB(38)GG$" "
681 PRINTCHR$(19)TAB(38)SP$"_"
1010 TT=(1/VAL(T$))*(3600-((VAL(T$)/70)*175)):REM CONTAINS A FUDGE FACTOR
1015 L=136-((1/VAL(T$))*4760):IFL<17THENL=17
1016 H=136+((1/VAL(T$))*4760):IFH>255THENH=255
1020 B=VAL(B$)
1030 IFB=6ANDBB$="8"THENB=2
1040 IFB=1THEN2010
1050 IFB=5ORB=7THENIFBB$>"1"THEN2050
1060 GOTO2020
2010 GOSUB2060:IFPEEK(K)=0THEN2010
2011 GOTO310
2020 GOSUB2060:FORI=1TO(B-1):GOSUB2080:NEXTI:IFPEEK(K)=0THEN2020
2021 GOTO310
2050 IFB=7THENGOSUB2060:GOSUB2080:IFPEEK(K)>0THEN310
2055 GOSUB2060:GOSUB2080:IFPEEK(K)>0THEN310
2057 GOSUB2060:GOSUB2080:GOSUB2080:IFPEEK(K)=0THEN2050
2058 GOTO310
2060 TI$="000000":GOSUB7310
2062 IFTI<3THEN2062
2063 POKES,0
2065 IFPEEK(K)>0THENRETURN
2066 P=PEEK(SPR)+5*D:IFP<LORP>HTHENP=PEEK(SPR)
2067 POKESPR,P:IFTI<TTTHEN2065
2070 POKES,33:D=D*-1:RETURN
2080 TI$="000000"
2082 IFTI<3THEN2082
2083 POKES,0
2085 IFPEEK(K)>0THENRETURN
2086 P=PEEK(SPR)+5*D:IFP<LORP>HTHENP=PEEK(SPR)
2087 POKESPR,P:IFTI<TTTHEN2085
2090 POKES,17:D=D*-1:RETURN
5000 REM **SOUNE SET-UP**
5010 FORI=54272TO54300:POKEI,0:NEXT
5020 POKE54273,200:POKE54277,4:POKE54296,15
5030 S=54276
5100 REM **SPRITE SET-UP**
5110 VIC=53248:SPR=VIC+2:POKEVIC+32,0:POKEVIC+33,6:POKEVIC+27,255
5115 POKEVIC+39,3:POKEVIC+40,7
5120 POKE2040,13:FORI=0TO14:POKE832+I,255:NEXT:FORI=15TO62:POKE832+I,0:NEXT
5121 POKE2041,14:FORI=0TO32:POKE896+I,255:NEXT:FORI=33TO62:POKE896+I,0:NEXT
5130 POKEVIC+21,3:POKEVIC,136:POKEVIC+2,136:POKEVIC+3,52
5500 REM **INITIALIZE VARIABLES**
5510 DN$="":REM CURSOR DOWN IN QUOTES
5511 AL$=""
5512 TP$=DN$+AL$
5513 BT$=DN$+TP$
5514 GG$=DN$+BT$
5515 SP$=DN$+GG$
5540 D=1:K=198
5550 TN=56328:SC=56329:MN=56330:HR=56331
5560 POKEHR,0:POKEMN,0:POKESC,0:POKETN,0
5570 PRINTCHR$(8):REM DISABLE UPPER/LOWER CASE SHIFT
6000 REM **SCREEN SET-UP**
6010 PRINTCHR$(142)CHR$(147)TAB(32)CHR$(18)CHR$(144)"  00:00 ";
6020 PRINTCHR$(146)CHR$(152)SPC(15)CHR$(193);
6021 PRINTSPC(16)CHR$(18)CHR$(144)"        ";:REM EIGHT SPACES IN QUOTES
6030 PRINTCHR$(146)CHR$(144);
6031 FORI=1TO14:PRINTCHR$(163);:NEXTI
6032 PRINTCHR$(152)CHR$(18)CHR$(169)" ";
6035 PRINTCHR$(223)CHR$(146)CHR$(144);
6036 FORI=1TO23:PRINTCHR$(163);:NEXTI:PRINTCHR$(152);
6040 PRINTSPC(3)CHR$(154)"GRAVE/LARGO "CHR$(152)CHR$(123);
6041 PRINTSPC(12)CHR$(144)"S"CHR$(152)
6050 PRINTSPC(9)CHR$(154)"LENTO "CHR$(152)CHR$(123);
6051 PRINTSPC(12)CHR$(144)"H "CHR$(176)" "CHR$(152)"CLOCK"
6060 PRINTSPC(8)CHR$(154)"ADAGIO "CHR$(152)CHR$(123);
6061 PRINTSPC(12)CHR$(144)"I"CHR$(195)CHR$(179)CHR$(152)
6070 PRINTSPC(5)CHR$(154)"LARGHETTO "CHR$(152)CHR$(123);
6071 PRINTSPC(12)CHR$(144)"F "CHR$(173)"  "CHR$(152)"QUIT"
6080 PRINTSPC(7)CHR$(154)"ANDANTE "CHR$(152)CHR$(123);
6081 PRINTSPC(12)CHR$(144)"T"CHR$(152)
6090 PRINTSPC(5)CHR$(154)"ANDANTINO "CHR$(152)CHR$(123);
6091 PRINTSPC(12)CHR$(144)CHR$(94)CHR$(152)
6100 PRINTSPC(6)CHR$(154)"MODERATO "CHR$(152)CHR$(123);
6101 PRINTSPC(12)CHR$(144)CHR$(202)CHR$(195)CHR$(195);
6102 PRINTCHR$(195)CHR$(195)CHR$(195)CHR$(201)CHR$(152)
6110 PRINTSPC(15)CHR$(123);
6111 PRINTSPC(12)CHR$(150)"120"CHR$(152)" TEMPO"
6115 T$="120":POKEVIC+1,.935*VAL(T$)+35.6
6120 PRINTSPC(4)CHR$(154)"ALLEGRETTO "CHR$(152)CHR$(123);
6121 PRINTSPC(12)CHR$(163)CHR$(163)CHR$(163)
6130 PRINTSPC(15)CHR$(123)
6140 PRINTSPC(7)CHR$(154)"ALLEGRO "CHR$(152)CHR$(123)
6150 PRINTSPC(15)CHR$(123);
6151 PRINTSPC(12)CHR$(150)"4/4"CHR$(152)"  BEAT"
6155 B$="4":BB$="4"
6160 PRINTSPC(9)CHR$(154)"ASSAI "CHR$(152)CHR$(123);
6161 PRINTSPC(12)CHR$(163)CHR$(163)CHR$(163)
6170 PRINTSPC(7)CHR$(154)"VIVACHE "CHR$(152)CHR$(123)
6180 PRINTSPC(15)CHR$(123)
6190 PRINTSPC(15)CHR$(123);
6191 PRINTSPC(19)"GO"
6200 PRINTSPC(8)CHR$(154)"PRESTO "CHR$(152)CHR$(123)
6210 PRINTSPC(15)CHR$(123)
6220 PRINTSPC(15)CHR$(123)
6230 PRINTSPC(3)CHR$(154)"PRESTISSIMO "CHR$(152)CHR$(123);
6231 PRINTSPC(17)"STOP"
6240 PRINTSPC(13)CHR$(152)CHR$(18)CHR$(169)"   "CHR$(127)CHR$(146)
6250 PRINTSPC(11)CHR$(152)CHR$(117)CHR$(18)"       ";:REM SEVEN SPACES IN QUOTE
6251 PRINTCHR$(146)CHR$(105)CHR$(145);
6999 RETURN
7000 REM **TIME SET ROUTINE**
7110 PRINTCHR$(19)TAB(38)DN$"_"
7120 GETA$:IFA$=CHR$(13)THEN7180
7125 IFA$<"/"ORA$>"9"THEN7120
7126 IFA$>"1"THENIFA$<":"THENHH=0:TH$="0":GOTO7146
7130 TH$=A$:PRINTCHR$(19)TAB(34)TH$" :  "
7131 HH=VAL(A$)*16
7140 GETA$:IFA$=<"/"ORA$>"9"THEN7140
7145 IFVAL(TH$+A$)>12THEN7140
7146 TH$=TH$+A$:PRINTCHR$(19)TAB(34)TH$":  "
7147 HL=VAL(A$)
7148 POKEHR,HH+HL
7150 GETA$:IFA$=<"/"ORA$>"5"THEN7150
7155 TM$=A$:PRINTCHR$(19)TAB(34)TH$":"TM$
7156 MH=VAL(A$)*16
7160 GETA$:IFA$=<"/"ORA$>"9"THEN7160
7164 TM$=TM$+A$
7165 PRINTCHR$(19)TAB(34)CHR$(18)CHR$(144)TH$":"TM$CHR$(146)CHR$(150)
7166 ML=VAL(A$)
7167 POKEMN,MH+ML
7168 POKESC,0:POKETN,0
7180 PRINTCHR$(19)TAB(38)DN$" "
7181 PRINTCHR$(19)TAB(38)AL$"_"
7200 REM **CHECK QUIT ROUTINE**
7220 GOSUB7300:GETA$:IFA$=""THEN7220
7230 IFA$=CHR$(141)THEN7500
7240 IFA$=CHR$(13)THEN7260
7250 GOTO7220
7260 PRINTCHR$(19)TAB(38)AL$" "
7270 GOTO310
7300 REM **UPDATE CLOCK ROUTINE**
7310 IFPEEK(MN)=(MH*16)+MLTHENRETURN
7320 HH=(PEEK(HR)AND112)/16:HL=(PEEK(HR)AND15)
7330 MH=(PEEK(MN)AND240)/16:ML=(PEEK(MN)AND15)
7335 DU=PEEK(TN)
7340 PRINTCHR$(19)CHR$(18)CHR$(144)TAB(34)CHR$(HH+48)CHR$(HL+48);
7341 PRINT":"CHR$(MH+48)+CHR$(ML+48)CHR$(146)CHR$(150)
7350 RETURN
7500 REM **QUIT ROUTINE**
7510 POKE53269,0
7520 PRINTCHR$(147)CHR$(154):POKE53280,14:POKE53281,6
7530 PRINTCHR$(9):POKE808,237
7540 END